SCONS

NAME

SYNOPSIS

DESCRIPTION

The scons utility builds software (or other files) by determining which component pieces must be rebuilt and executing the necessary commands to rebuild them.

By default, scons searches for a file named SConstruct, Sconstruct, or sconstruct (in that order) in the current directory and reads its configuration from the first file found. An alternate file name may be specified via the -f option.

The SConstruct file can specify subsidiary configuration files using the SConscript() function. By convention, these subsidiary files are named SConscript, although any name may be used. (Because of this naming convention, the term "SConscript files" is sometimes used to refer generically to all scons configuration files, regardless of actual file name.)

The configuration files specify the target files to be built, and (optionally) the rules to build those targets. Reasonable default rules exist for building common software components (executable programs, object files, libraries), so that for most software projects, only the target and input files need be specified.

Before reading the SConstruct file, scons adds looks for a dir named site_scons in the dir containing the SConstruct file; it adds that site_scons to sys.path, reads the file site_scons/site_init.py, and adds the directory site_scons/site_tools to the default toolpath, if those exist. See the --no-site-dir and --site-dir options for more details.

scons reads and executes the SConscript files as Python scripts, so you may use normal Python scripting capabilities (such as flow control, data manipulation, and imported Python libraries) to handle complicated build situations. scons, however, reads and executes all of the SConscript files before it begins building any targets. To make this obvious, scons prints the following messages about what it is doing:

$ scons foo.out
scons: Reading SConscript files ...
scons: done reading SConscript files.
scons: Building targets  ...
cp foo.in foo.out
scons: done building targets.
$

The status messages (everything except the line that reads "cp foo.in foo.out") may be suppressed using the -Q option.

scons does not automatically propagate the external environment used to execute scons to the commands used to build target files. This is so that builds will be guaranteed repeatable regardless of the environment variables set at the time scons is invoked. This also means that if the compiler or other commands that you want to use to build your target files are not in standard system locations, scons will not find them unless you explicitly set the PATH to include those locations. Whenever you create an scons construction environment, you can propagate the value of PATH from your external environment as follows:

import os
env = Environment(ENV = {'PATH' : os.environ['PATH']})

Similarly, if the commands use external environment variables like $PATH, $HOME, $JAVA_HOME, $LANG, $SHELL, $TERM, etc., these variables can also be explicitly propagated:

import os
env = Environment(ENV = {'PATH' : os.environ['PATH'],
                         'HOME' : os.environ['HOME']})

Or you may explicitly propagate the invoking user's complete external environment:

import os
env = Environment(ENV = os.environ)

This comes at the expense of making your build dependent on the user's environment being set correctly, but it may be more convenient for many configurations.

scons can scan known input files automatically for dependency information (for example, #include statements in C or C++ files) and will rebuild dependent files appropriately whenever any "included" input file changes. scons supports the ability to define new scanners for unknown input file types.

scons knows how to fetch files automatically from SCCS or RCS subdirectories using SCCS, RCS or BitKeeper.

scons is normally executed in a top-level directory containing a SConstruct file, optionally specifying as command-line arguments the target file or files to be built.

By default, the command

scons

will build all target files in or below the current directory. Explicit default targets (to be built when no targets are specified on the command line) may be defined the SConscript file(s) using the Default() function, described below.

Even when Default() targets are specified in the SConscript file(s), all target files in or below the current directory may be built by explicitly specifying the current directory (.) as a command-line target:

scons .

Building all target files, including any files outside of the current directory, may be specified by supplying a command-line target of the root directory (on POSIX systems):

scons /

or the path name(s) of the volume(s) in which all the targets should be built (on Windows systems):

scons C:\ D:\

To build only specific targets, supply them as command-line arguments:

scons foo bar

in which case only the specified targets will be built (along with any derived files on which they depend).

Specifying "cleanup" targets in SConscript files is not necessary. The -c flag removes all files necessary to build the specified target:

scons -c .

to remove all target files, or:

scons -c build export

to remove target files under build and export. Additional files or directories to remove can be specified using the Clean() function. Conversely, targets that would normally be removed by the -c invocation can be prevented from being removed by using the NoClean() function.

A subset of a hierarchical tree may be built by remaining at the top-level directory (where the SConstruct file lives) and specifying the subdirectory as the target to be built:

scons src/subdir

or by changing directory and invoking scons with the -u option, which traverses up the directory hierarchy until it finds the SConstruct file, and then builds targets relatively to the current subdirectory:

cd src/subdir
scons -u .

scons supports building multiple targets in parallel via a -j option that takes, as its argument, the number of simultaneous tasks that may be spawned:

scons -j 4

builds four targets in parallel, for example.

scons can maintain a cache of target (derived) files that can be shared between multiple builds. When caching is enabled in a SConscript file, any target files built by scons will be copied to the cache. If an up-to-date target file is found in the cache, it will be retrieved from the cache instead of being rebuilt locally. Caching behavior may be disabled and controlled in other ways by the --cache-force, --cache-disable, and --cache-show command-line options. The --random option is useful to prevent multiple builds from trying to update the cache simultaneously.

Values of variables to be passed to the SConscript file(s) may be specified on the command line:

scons debug=1 .

These variables are available in SConscript files through the ARGUMENTS dictionary, and can be used in the SConscript file(s) to modify the build in any way:

if ARGUMENTS.get('debug', 0):
    env = Environment(CCFLAGS = '-g')
else:
    env = Environment()

The command-line variable arguments are also available in the ARGLIST list, indexed by their order on the command line. This allows you to process them in order rather than by name, if necessary. ARGLIST[0] returns a tuple containing (argname, argvalue). A Python exception is thrown if you try to access a list member that does not exist.

scons requires Python version 1.5.2 or later. There should be no other dependencies or requirements to run scons.

By default, scons knows how to search for available programming tools on various systems. On Windows systems, scons searches in order for the Microsoft Visual C++ tools, the MinGW tool chain, the Intel compiler tools, and the PharLap ETS compiler. On OS/2 systems, scons searches in order for the OS/2 compiler, the GCC tool chain, and the Microsoft Visual C++ tools, On SGI IRIX, IBM AIX, Hewlett Packard HP-UX, and Sun Solaris systems, scons searches for the native compiler tools (MIPSpro, Visual Age, aCC, and Forte tools respectively) and the GCC tool chain. On all other platforms, including POSIX (Linux and UNIX) platforms, scons searches in order for the GCC tool chain, the Microsoft Visual C++ tools, and the Intel compiler tools. You may, of course, override these default values by appropriate configuration of Environment construction variables.

OPTIONS

-b

Ignored for compatibility with non-GNU versions of make.

-c, --clean, --remove

Clean up by removing all target files for which a construction command is specified. Also remove any files or directories associated to the construction command using the Clean() function. Will not remove any targets specified by the NoClean() function.

--cache-debug=file

Print debug information about the CacheDir() derived-file caching to the specified file. If file is - (a hyphen), the debug information are printed to the standard output. The printed messages describe what signature file names are being looked for in, retrieved from, or written to the CacheDir() directory tree.

--cache-disable, --no-cache

Disable the derived-file caching specified by CacheDir(). scons will neither retrieve files from the cache nor copy files to the cache.

--cache-force, --cache-populate

When using CacheDir(), populate a cache by copying any already-existing, up-to-date derived files to the cache, in addition to files built by this invocation. This is useful to populate a new cache with all the current derived files, or to add to the cache any derived files recently built with caching disabled via the --cache-disable option.

--cache-show

When using CacheDir() and retrieving a derived file from the cache, show the command that would have been executed to build the file, instead of the usual report, "Retrieved `file' from cache." This will produce consistent output for build logs, regardless of whether a target file was rebuilt or retrieved from the cache.

--config=mode

This specifies how the Configure call should use or generate the results of configuration tests. The option should be specified from among the following choices:

--config=auto

scons will use its normal dependency mechanisms to decide if a test must be rebuilt or not. This saves time by not running the same configuration tests every time you invoke scons, but will overlook changes in system header files or external commands (such as compilers) if you don't specify those dependecies explicitly. This is the default behavior.

--config=force

If this option is specified, all configuration tests will be re-run regardless of whether the cached results are out of date. This can be used to explicitly force the configuration tests to be updated in response to an otherwise unconfigured change in a system header file or compiler.

--config=cache

If this option is specified, no configuration tests will be rerun and all results will be taken from cache. Note that scons will still consider it an error if --config=cache is specified and a necessary test does not yet have any results in the cache.

-C directory, --directory=directory

Change to the specified directory before searching for the SConstruct, Sconstruct, or sconstruct file, or doing anything else. Multiple -C options are interpreted relative to the previous one, and the right-most -C option wins. (This option is nearly equivalent to -f directory/SConstruct, except that it will search for SConstruct, Sconstruct, or sconstruct in the specified directory.)

-D

Works exactly the same way as the -u option except for the way default targets are handled. When this option is used and no targets are specified on the command line, all default targets are built, whether or not they are below the current directory.

--debug=type

Debug the build process. type specifies what type of debugging:

--debug=count

Print how many objects are created of the various classes used internally by SCons before and after reading the SConscript files and before and after building targets. This only works when run under Python 2.1 or later.

--debug=dtree

A synonym for the newer --tree=derived option. This will be deprecated in some future release and ultimately removed.

--debug=explain

Print an explanation of precisely why scons is deciding to (re-)build any targets. (Note: this does not print anything for targets that are not rebuilt.)

--debug=findlibs

Instruct the scanner that searches for libraries to print a message about each potential library name it is searching for, and about the actual libraries it finds.

--debug=includes

Print the include tree after each top-level target is built. This is generally used to find out what files are included by the sources of a given derived file:

$ scons --debug=includes foo.o

--debug=memoizer

Prints a summary of hits and misses using the Memoizer, an internal subsystem that counts how often SCons uses cached values in memory instead of recomputing them each time they're needed. Only available when using Python 2.2 or later.

--debug=memory

Prints how much memory SCons uses before and after reading the SConscript files and before and after building targets.

--debug=nomemoizer

A deprecated option preserved for backwards compatibility.

--debug=objects

Prints a list of the various objects of the various classes used internally by SCons. This only works when run under Python 2.1 or later.

--debug=pdb

Re-run SCons under the control of the pdb Python debugger.

--debug=presub

Print the raw command line used to build each target before the construction environment variables are substituted. Also shows which targets are being built by this command. Output looks something like this:

$ scons --debug=presub
Building myprog.o with action(s):
  $SHCC $SHCFLAGS $SHCCFLAGS $CPPFLAGS $_CPPINCFLAGS -c -o $TARGET $SOURCES

--debug=stacktrace

Prints an internal Python stack trace when encountering an otherwise unexplained error.

--debug=stree

A synonym for the newer --tree=all,status option. This will be deprecated in some future release and ultimately removed.

--debug=time

Prints various time profiling information: the time spent executing each individual build command; the total build time (time SCons ran from beginning to end); the total time spent reading and executing SConscript files; the total time spent SCons itself spend running (that is, not counting reading and executing SConscript files); and both the total time spent executing all build commands and the elapsed wall-clock time spent executing those build commands. (When scons is executed without the -j option, the elapsed wall-clock time will typically be slightly longer than the total time spent executing all the build commands, due to the SCons processing that takes place in between executing each command. When scons is executed with the -j option, and your build configuration allows good parallelization, the elapsed wall-clock time should be significantly smaller than the total time spent executing all the build commands, since multiple build commands and intervening SCons processing should take place in parallel.)

--debug=tree

A synonym for the newer --tree=all option. This will be deprecated in some future release and ultimately removed.

--diskcheck=types

Enable specific checks for whether or not there is a file on disk where the SCons configuration expects a directory (or vice versa), and whether or not RCS or SCCS sources exist when searching for source and include files. The types argument can be set to: all, to enable all checks explicitly (the default behavior); none, to disable all such checks; match, to check that files and directories on disk match SCons' expected configuration; rcs, to check for the existence of an RCS source for any missing source or include files; sccs, to check for the existence of an SCCS source for any missing source or include files. Multiple checks can be specified separated by commas; for example, --diskcheck=sccs,rcs would still check for SCCS and RCS sources, but disable the check for on-disk matches of files and directories. Disabling some or all of these checks can provide a performance boost for large configurations, or when the configuration will check for files and/or directories across networked or shared file systems, at the slight increased risk of an incorrect build or of not handling errors gracefully (if include files really should be found in SCCS or RCS, for example, or if a file really does exist where the SCons configuration expects a directory).

--duplicate=ORDER

There are three ways to duplicate files in a build tree: hard links, soft (symbolic) links and copies. The default behaviour of SCons is to prefer hard links to soft links to copies. You can specify different behaviours with this option. ORDER must be one of hard-soft-copy (the default), soft-hard-copy, hard-copy, soft-copy or copy. SCons will attempt to duplicate files using the mechanisms in the specified order.

-f file, --file=file, --makefile=file, --sconstruct=file

Use file as the initial SConscript file.

-h, --help

Print a local help message for this build, if one is defined in the SConscript file(s), plus a line that describes the -H option for command-line option help. If no local help message is defined, prints the standard help message about command-line options. Exits after displaying the appropriate message.

-H, --help-options

Print the standard help message about command-line options and exit.

-i, --ignore-errors

Ignore all errors from commands executed to rebuild files.

-I directory, --include-dir=directory

Specifies a directory to search for imported Python modules. If several -I options are used, the directories are searched in the order specified.

--implicit-cache

Cache implicit dependencies. This causes scons to use the implicit (scanned) dependencies from the last time it was run instead of scanning the files for implicit dependencies. This can significantly speed up SCons, but with the following limitations:

scons will not detect changes to implicit dependency search paths (e.g. CPPPATH, LIBPATH) that would ordinarily cause different versions of same-named files to be used.

scons will miss changes in the implicit dependencies in cases where a new implicit dependency is added earlier in the implicit dependency search path (e.g. CPPPATH, LIBPATH) than a current implicit dependency with the same name.

--implicit-deps-changed

Forces SCons to ignore the cached implicit dependencies. This causes the implicit dependencies to be rescanned and recached. This implies --implicit-cache.

--implicit-deps-unchanged

Force SCons to ignore changes in the implicit dependencies. This causes cached implicit dependencies to always be used. This implies --implicit-cache.

-j N, --jobs=N

Specifies the number of jobs (commands) to run simultaneously. If there is more than one -j option, the last one is effective.

-k, --keep-going

Continue as much as possible after an error. The target that failed and those that depend on it will not be remade, but other targets specified on the command line will still be processed.

-m

Ignored for compatibility with non-GNU versions of make.

--max-drift=SECONDS

Set the maximum expected drift in the modification time of files to SECONDS. This value determines how long a file must be unmodified before its cached content signature will be used instead of calculating a new content signature (MD5 checksum) of the file's contents. The default value is 2 days, which means a file must have a modification time of at least two days ago in order to have its cached content signature used. A negative value means to never cache the content signature and to ignore the cached value if there already is one. A value of 0 means to always use the cached signature, no matter how old the file is.

-n, --just-print, --dry-run, --recon

No execute. Print the commands that would be executed to build any out-of-date target files, but do not execute the commands.

--no-site-dir

Prevents the automatic addition of the standard site_scons dir to sys.path. Also prevents loading the site_scons/site_init.py module if it exists, and prevents adding site_scons/site_tools to the toolpath.

--profile=file

Run SCons under the Python profiler and save the results in the specified file. The results may be analyzed using the Python pstats module.

-q, --question

Do not run any commands, or print anything. Just return an exit status that is zero if the specified targets are already up to date, non-zero otherwise.

-Q

Quiets SCons status messages about reading SConscript files, building targets and entering directories. Commands that are executed to rebuild target files are still printed.

--random

Build dependencies in a random order. This is useful when building multiple trees simultaneously with caching enabled, to prevent multiple builds from simultaneously trying to build or retrieve the same target files.

-s, --silent, --quiet

Silent. Do not print commands that are executed to rebuild target files. Also suppresses SCons status messages.

-S, --no-keep-going, --stop

Ignored for compatibility with GNU make.

--site-dir=dir

Uses the named dir as the site dir rather than the default site_scons dir. This dir will get prepended to sys.path, the module dir/site_init.py will get loaded if it exists, and dir/site_tools will get added to the default toolpath.

-t, --touch

Ignored for compatibility with GNU make. (Touching a file to make it appear up-to-date is unnecessary when using scons.)

--taskmastertrace=file

Prints trace information to the specified file about how the internal Taskmaster object evaluates and controls the order in which Nodes are built. A file name of - may be used to specify the standard output.

-tree=options

Prints a tree of the dependencies after each top-level target is built. This prints out some or all of the tree, in various formats, depending on the options specified:

--tree=all

Print the entire dependency tree after each top-level target is built. This prints out the complete dependency tree, including implicit dependencies and ignored dependencies.

--tree=derived

Restricts the tree output to only derived (target) files, not source files.

--tree=status

Prints status information for each displayed node.

--tree=prune

Prunes the tree to avoid repeating dependency information for nodes that have already been displayed. Any node that has already been displayed will have its name printed in [square brackets], as an indication that the dependencies for that node can be found by searching for the relevant output higher up in the tree.

Multiple options may be specified, separated by commas:

# Prints only derived files, with status information:
scons --tree=derived,status

# Prints all dependencies of target, with status information
# and pruning dependencies of already-visited Nodes:
scons --tree=all,prune,status target

-u, --up, --search-up

Walks up the directory structure until an SConstruct , Sconstruct or sconstruct file is found, and uses that as the top of the directory tree. If no targets are specified on the command line, only targets at or below the current directory will be built.

-U

Works exactly the same way as the -u option except for the way default targets are handled. When this option is used and no targets are specified on the command line, all default targets that are defined in the SConscript(s) in the current directory are built, regardless of what directory the resultant targets end up in.

-v, --version

Print the scons version, copyright information, list of authors, and any other relevant information. Then exit.

-w, --print-directory

Print a message containing the working directory before and after other processing.

--no-print-directory

Turn off -w, even if it was turned on implicitly.

--warn=type, --warn=no-type

Enable or disable warnings. type specifies the type of warnings to be enabled or disabled:

--warn=all, --warn=no-all

Enables or disables all warnings.

--warn=cache-write-error, --warn=no-cache-write-error

Enables or disables warnings about errors trying to write a copy of a built file to a specified CacheDir(). These warnings are disabled by default.

--warn=corrupt-sconsign, --warn=no-corrupt-sconsign

Enables or disables warnings about unfamiliar signature data in .sconsign files. These warnings are enabled by default.

--warn=dependency, --warn=no-dependency

Enables or disables warnings about dependencies. These warnings are disabled by default.

--warn=deprecated, --warn=no-deprecated

Enables or disables warnings about use of deprecated features. These warnings are enabled by default.

--warn=duplicate-environment, --warn=no-duplicate-environment

Enables or disables warnings about missing SConscript files.

--warn=misleading-keywords, --warn=no-misleading-keywords

Enables or disables warnings about use of the misspelled keywords targets and sources when calling Builders. (Note the last s characters, the correct spellings are target and source.) These warnings are enabled by default.

--warn=missing-sconscript, --warn=no-missing-sconscript

Enables or disables warnings about attempts to specify a build of a target with two different construction environments that use the same action. These warnings are enabled by default.

--warn=no-md5-module, --warn=no-no-md5-module

Enables or disables warnings about the version of Python not having an MD5 checksum module available. These warnings are enabled by default.

--warn=no-metaclass-support, --warn=no-no-metaclass-support

Enables or disables warnings about the version of Python not supporting metaclasses when the --debug=memoizer option is used. These warnings are enabled by default.

--warn=no-parallel-support, --warn=no-no-parallel-support

Enables or disables warnings about the version of Python not being able to support parallel builds when the -j option is used. These warnings are enabled by default.

--warn=reserved-variable, --warn=no-reserved-variable

Enables or disables warnings about attempts to set the reserved construction variable names TARGET, TARGETS, SOURCE or SOURCES. These warnings are disabled by default.

-Y repository, --repository=repository, --srcdir=repository

Search the specified repository for any input and target files not found in the local directory hierarchy. Multiple -Y options may specified, in which case the repositories are searched in the order specified.

CONFIGURATION FILE REFERENCE

Construction Environments

env = Environment()

By default, a new construction environment is initialized with a set of builder methods and construction variables that are appropriate for the current platform. An optional platform keyword argument may be used to specify that an environment should be initialized for a different platform:

env = Environment(platform = 'cygwin')
env = Environment(platform = 'os2')
env = Environment(platform = 'posix')
env = Environment(platform = 'win32')

Specifying a platform initializes the appropriate construction variables in the environment to use and generate file names with prefixes and suffixes appropriate for the platform.

Note that the win32 platform adds the SYSTEMDRIVE and SYSTEMROOT variables from the user's external environment to the construction environment's ENV dictionary. This is so that any executed commands that use sockets to connect with other systems (such as fetching source files from external CVS repository specifications like :pserver:anonymous@cvs.sourceforge.net:/cvsroot/scons) will work on Windows systems.

The platform argument may be function or callable object, in which case the Environment() method will call the specified argument to update the new construction environment:

def my_platform(env):
    env['VAR'] = 'xyzzy'

env = Environment(platform = my_platform)

Additionally, a specific set of tools with which to initialize the environment may specified as an optional keyword argument:

env = Environment(tools = ['msvc', 'lex'])

Non-built-in tools may be specified using the toolpath argument:

env = Environment(tools = ['default', 'foo'], toolpath = ['tools'])

This looks for a tool specification in tools/foo.py (as well as using the ordinary default tools for the platform). foo.py should have two functions: generate(env, **kw) and exists(env). The generate() function modifies the passed-in environment to set up variables so that the tool can be executed; it may use any keyword arguments that the user supplies (see below) to vary its initialization. The exists() function should return a true value if the tool is available. Tools in the toolpath are used before any of the built-in ones. For example, adding gcc.py to the toolpath would override the built-in gcc tool. Also note that the toolpath is stored in the environment for use by later calls to Clone() and Tool() methods:

base = Environment(toolpath=['custom_path'])
derived = base.Clone(tools=['custom_tool'])
derived.CustomBuilder()

The elements of the tools list may also be functions or callable objects, in which case the Environment() method will call the specified elements to update the new construction environment:

def my_tool(env):
    env['XYZZY'] = 'xyzzy'

env = Environment(tools = [my_tool])

The individual elements of the tools list may also themselves be two-element lists of the form (toolname, kw_dict). SCons searches for the toolname specification file as described above, and passes kw_dict, which must be a dictionary, as keyword arguments to the tool's generate function. The generate function can use the arguments to modify the tool's behavior by setting up the environment in different ways or otherwise changing its initialization.

# in tools/my_tool.py:
def generate(env, **kw):
  # Sets MY_TOOL to the value of keyword argument 'arg1' or 1.
  env['MY_TOOL'] = kw.get('arg1', '1')
def exists(env):
  return 1

# in SConstruct:
env = Environment(tools = ['default', ('my_tool', {'arg1': 'abc'})],
                  toolpath=['tools'])

The tool definition (i.e. my_tool()) can use the PLATFORM variable from the environment it receives to customize the tool for different platforms.

If no tool list is specified, then SCons will auto-detect the installed tools using the PATH variable in the ENV construction variable and the platform name when the Environment is constructed. Changing the PATH variable after the Environment is constructed will not cause the tools to be redetected.

SCons supports the following tool specifications out of the box:

386asm
aixc++
aixcc
aixf77
aixlink
ar
as
bcc32
c++
cc
cvf
dmd
dvipdf
dvips
f77
f90
f95
fortran
g++
g77
gas
gcc
gnulink
gs
hpc++
hpcc
hplink
icc
icl
ifl
ifort
ilink
ilink32
intelc
jar
javac
javah
latex
lex
link
linkloc
m4
masm
midl
mingw
mslib
mslink
msvc
msvs
mwcc
mwld
nasm
pdflatex
pdftex
qt
rmic
rpcgen
sgiar
sgic++
sgicc
sgilink
sunar
sunc++
suncc
sunlink
swig
tar
tex
tlib
yacc
zip

Additionally, there is a "tool" named default which configures the environment with a default set of tools for the current platform.

On posix and cygwin platforms the GNU tools (e.g. gcc) are preferred by SCons, on Windows the Microsoft tools (e.g. msvc) followed by MinGW are preferred by SCons, and in OS/2 the IBM tools (e.g. icc) are preferred by SCons.

Builder Methods

Build rules are specified by calling a construction environment's builder methods. The arguments to the builder methods are target (a list of target files) and source (a list of source files).

Because long lists of file names can lead to a lot of quoting, scons supplies a Split() global function and a same-named environment method that split a single string into a list, separated on strings of white-space characters. (These are similar to the string.split() method from the standard Python library, but work even if the input isn't a string.)

Like all Python arguments, the target and source arguments to a builder method can be specified either with or without the "target" and "source" keywords. When the keywords are omitted, the target is first, followed by the source. The following are equivalent examples of calling the Program builder method:

env.Program('bar', ['bar.c', 'foo.c'])
env.Program('bar', Split('bar.c foo.c'))
env.Program('bar', env.Split('bar.c foo.c'))
env.Program(source =  ['bar.c', 'foo.c'], target = 'bar')
env.Program(target = 'bar', Split('bar.c foo.c'))
env.Program(target = 'bar', env.Split('bar.c foo.c'))
env.Program('bar', source = string.split('bar.c foo.c'))

When the target shares the same base name as the source and only the suffix varies, and if the builder method has a suffix defined for the target file type, then the target argument may be omitted completely, and scons will deduce the target file name from the source file name. The following examples all build the executable program bar (on POSIX systems) or bar.exe (on Windows systems) from the bar.c source file:

env.Program(target = 'bar', source = 'bar.c')
env.Program('bar', source = 'bar.c')
env.Program(source = 'bar.c')
env.Program('bar.c')

As a convenience, a srcdir keyword argument may be specified when calling a Builder. When specified, all source file strings that are not absolute paths will be interpreted relative to the specified srcdir. The following example will build the build/prog (or build/prog.exe on Windows) program from the files src/f1.c and src/f2.c:

env.Program('build/prog', ['f1.c', 'f2.c'], srcdir='src')

It is possible to override or add construction variables when calling a builder method by passing additional keyword arguments. These overridden or added variables will only be in effect when building the target, so they will not affect other parts of the build. For example, if you want to add additional libraries for just one program:

env.Program('hello', 'hello.c', LIBS=['gl', 'glut'])

or generate a shared library with a non-standard suffix:

env.SharedLibrary('word', 'word.cpp',
                  SHLIBSUFFIX='.ocx',
                  LIBSUFFIXES=['.ocx'])

(Note that both the $SHLIBSUFFIX and $LIBSUFFIXES variables must be set if you want SCons to search automatically for dependencies on the non-standard library names; see the descriptions of these variables, below, for more information.)

Although the builder methods defined by scons are, in fact, methods of a construction environment object, they may also be called without an explicit environment:

Program('hello', 'hello.c')
SharedLibrary('word', 'word.cpp')

In this case, the methods are called internally using a default construction environment that consists of the tools and values that scons has determined are appropriate for the local system.

Builder methods that can be called without an explicit environment may be called from custom Python modules that you import into an SConscript file by adding the following to the Python module:

from SCons.Script import *

All builder methods return a list of Nodes that represent the target or targets that will be built. A Node is an internal SCons object which represents build targets or sources.

The returned Node(s) can be passed to other builder methods as source(s) or passed to any SCons function or method where a filename would normally be accepted. For example, if it were necessary to add a specific -D flag when compiling one specific object file:

bar_obj_list = env.StaticObject('bar.c', CPPDEFINES='-DBAR')
env.Program(source = ['foo.c', bar_obj_list, 'main.c'])

Using a Node in this way makes for a more portable build by avoiding having to specify a platform-specific object suffix when calling the Program() builder method.

Note that Builder calls will automatically "flatten" the source and target file lists, so it's all right to have the bar_obj list return by the StaticObject() call in the middle of the source file list. If you need to manipulate a list of lists returned by Builders directly using Python, you can either build the list by hand:

foo = Object('foo.c')
bar = Object('bar.c')
objects = ['begin.o'] + foo + ['middle.o'] + bar + ['end.o']
for object in objects:
    print str(object)

Or you can use the Flatten() supplied by scons to create a list containing just the Nodes, which may be more convenient:

foo = Object('foo.c')
bar = Object('bar.c')
objects = Flatten(['begin.o', foo, 'middle.o', bar, 'end.o'])
for object in objects:
    print str(object)

The path name for a Node's file may be used by passing the Node to the Python-builtin str() function:

bar_obj_list = env.StaticObject('bar.c', CPPDEFINES='-DBAR')
print "The path to bar_obj is:", str(bar_obj_list[0])

Note again that because the Builder call returns a list, we have to access the first element in the list (bar_obj_list[0]) to get at the Node that actually represents the object file.

Builder calls support a chdir keyword argument that specifies that the Builder's action(s) should be executed after changing directory. If the chdir argument is a string or a directory Node, scons will change to the specified directory. If the chdir is not a string or Node and is non-zero, then scons will change to the target file's directory.

# scons will change to the "sub" subdirectory
# before executing the "cp" command.
env.Command('sub/dir/foo.out', 'sub/dir/foo.in',
            "cp dir/foo.in dir/foo.out",
            chdir='sub')

# Because chdir is not a string, scons will change to the
# target's directory ("sub/dir") before executing the
# "cp" command.
env.Command('sub/dir/foo.out', 'sub/dir/foo.in',
            "cp foo.in foo.out",
            chdir=1)

Note that scons will not automatically modify its expansion of construction variables like $TARGET and $SOURCE when using the chdir keyword argument--that is, the expanded file names will still be relative to the top-level SConstruct directory, and consequently incorrect relative to the chdir directory. If you use the chdir keyword argument, you will typically need to supply a different command line using expansions like ${TARGET.file} and ${SOURCE.file} to use just the filename portion of the targets and source.

scons provides the following builder methods:

CFile()

env.CFile()

Builds a C source file given a lex (.l) or yacc (.y) input file. The suffix specified by the $CFILESUFFIX construction variable (.c by default) is automatically added to the target if it is not already present. Example:

# builds foo.c
env.CFile(target = 'foo.c', source = 'foo.l')
# builds bar.c
env.CFile(target = 'bar', source = 'bar.y')

CXXFile()

env.CXXFile()

Builds a C++ source file given a lex (.ll) or yacc (.yy) input file. The suffix specified by the $CXXFILESUFFIX construction variable (.cc by default) is automatically added to the target if it is not already present. Example:

# builds foo.cc
env.CXXFile(target = 'foo.cc', source = 'foo.ll')
# builds bar.cc
env.CXXFile(target = 'bar', source = 'bar.yy')

DVI()

env.DVI()

Builds a .dvi file from a .tex, .ltx or .latex input file. If the source file suffix is .tex, scons will examine the contents of the file; if the string \documentclass or \documentstyle is found, the file is assumed to be a LaTeX file and the target is built by invoking the $LATEXCOM command line; otherwise, the $TEXCOM command line is used. If the file is a LaTeX file, the DVI() builder method will also examine the contents of the .aux file and invoke the $BIBTEX command line if the string bibdata is found, start $MAKEINDEX to generate an index if a .ind file is found and will examine the contents .log file and re-run the $LATEXCOM command if the log file says it is necessary.

The suffix .dvi (hard-coded within TeX itself) is automatically added to the target if it is not already present. Examples:

# builds from aaa.tex
env.DVI(target = 'aaa.dvi', source = 'aaa.tex')
# builds bbb.dvi
env.DVI(target = 'bbb', source = 'bbb.ltx')
# builds from ccc.latex
env.DVI(target = 'ccc.dvi', source = 'ccc.latex')

Jar()

env.Jar()

Builds a Java archive (.jar) file from a source tree of .class files. If the $JARCHDIR value is set, the jar command will change to the specified directory using the -C option. If the contents any of the source files begin with the string Manifest-Version, the file is assumed to be a manifest and is passed to the jar command with the m option set.

env.Jar(target = 'foo.jar', source = 'classes')

Java()

env.Java()

Builds one or more Java class files from one or more source trees of .java files. The class files will be placed underneath the specified target directory. SCons will parse each source .java file to find the classes (including inner classes) defined within that file, and from that figure out the target .class files that will be created. SCons will also search each Java file for the Java package name, which it assumes can be found on a line beginning with the string package in the first column; the resulting .class files will be placed in a directory reflecting the specified package name. For example, the file Foo.java defining a single public Foo class and containing a package name of sub.dir will generate a corresponding sub/dir/Foo.class class file.

Example:

env.Java(target = 'classes', source = 'src')
env.Java(target = 'classes', source = ['src1', 'src2'])

JavaH()

env.JavaH()

Builds C header and source files for implementing Java native methods. The target can be either a directory in which the header files will be written, or a header file name which will contain all of the definitions. The source can be either the names of .class files, or the objects returned from the Java() builder method.

If the construction variable $JAVACLASSDIR is set, either in the environment or in the call to the JavaH() builder method itself, then the value of the variable will be stripped from the beginning of any .class file names.

Examples:

# builds java_native.h
classes = env.Java(target = 'classdir', source = 'src')
env.JavaH(target = 'java_native.h', source = classes)

# builds include/package_foo.h and include/package_bar.h
env.JavaH(target = 'include',
          source = ['package/foo.class', 'package/bar.class'])

# builds export/foo.h and export/bar.h
env.JavaH(target = 'export',
          source = ['classes/foo.class', 'classes/bar.class'],
          JAVACLASSDIR = 'classes')

Library()

env.Library()

A synonym for the StaticLibrary() builder method.

LoadableModule()

env.LoadableModule()

On most systems, this is the same as SharedLibrary(). On Mac OS X (Darwin) platforms, this creates a loadable module bundle.

M4()

env.M4()

Builds an output file from an M4 input file. This uses a default $M4FLAGS value of -E, which considers all warnings to be fatal and stops on the first warning when using the GNU version of m4. Example:

env.M4(target = 'foo.c', source = 'foo.c.m4')

Moc()

env.Moc()

Builds an output file from a moc input file. Moc input files are either header files or cxx files. This builder is only available after using the tool 'qt'. See the $QTDIR variable for more information. Example:

env.Moc('foo.h') # generates moc_foo.cc
env.Moc('foo.cpp') # generates foo.moc

MSVSProject()

env.MSVSProject()

Builds a Microsoft Visual Studio project file, and by default builds a solution file as well.

This builds a Visual Studio project file, based on the version of Visual Studio that is configured (either the latest installed version, or the version specified by $MSVS_VERSION in the Environment constructor). For Visual Studio 6, it will generate a .dsp file. For Visual Studio 7 (.NET) and later versions, it will generate a .vcproj file.

By default, this also generates a solution file for the specified project, a .dsw file for Visual Studio 6 or a .sln file for Visual Studio 7 (.NET). This behavior may be disabled by specifying auto_build_solution=0 when you call MSVSProject(), in which case you presumably want to build the solution file(s) by calling the MSVSSolution() Builder (see below).

It takes several lists of filenames to be placed into the project file. These are currently limited to srcs, incs, localincs, resources, and misc. These are pretty self-explanatory, but it should be noted that these lists are added to the $SOURCES construction variable as strings, NOT as SCons File Nodes. This is because they represent file names to be added to the project file, not the source files used to build the project file.

The above filename lists are all optional, although at least one must be specified for the resulting project file to be non-empty.

In addition to the above lists of values, the following values may be specified:

target: The name of the target .dsp or .vcproj file. The correct suffix for the version of Visual Studio must be used, but the $MSVSPROJECTSUFFIX construction variable will be defined to the correct value (see example below).

variant: The name of this particular variant. For Visual Studio 7 projects, this can also be a list of variant names. These are typically things like "Debug" or "Release", but really can be anything you want. For Visual Studio 7 projects, they may also specify a target platform separated from the variant name by a | (vertical pipe) character: Debug|Xbox. The default target platform is Win32. Multiple calls to MSVSProject() with different variants are allowed; all variants will be added to the project file with their appropriate build targets and sources.

buildtarget: An optional string, node, or list of strings or nodes (one per build variant), to tell the Visual Studio debugger what output target to use in what build variant. The number of buildtarget entries must match the number of variant entries.

runfile: The name of the file that Visual Studio 7 and later will run and debug. This appears as the value of the Output field in the resutling Visual Studio project file. If this is not specified, the default is the same as the specified buildtarget value.

Example usage:

barsrcs = ['bar.cpp'],
barincs = ['bar.h'],
barlocalincs = ['StdAfx.h']
barresources = ['bar.rc','resource.h']
barmisc = ['bar_readme.txt']

dll = env.SharedLibrary(target = 'bar.dll',
                        source = barsrcs)

env.MSVSProject(target = 'Bar' + env['MSVSPROJECTSUFFIX'],
                srcs = barsrcs,
                incs = barincs,
                localincs = barlocalincs,
                resources = barresources,
                misc = barmisc,
                buildtarget = dll,
                variant = 'Release')

MSVSSolution()

env.MSVSSolution()

Builds a Microsoft Visual Studio solution file.

This builds a Visual Studio solution file, based on the version of Visual Studio that is configured (either the latest installed version, or the version specified by $MSVS_VERSION in the construction environment). For Visual Studio 6, it will generate a .dsw file. For Visual Studio 7 (.NET), it will generate a .sln file.

The following values must be specified:

target: The name of the target .dsw or .sln file. The correct suffix for the version of Visual Studio must be used, but the value $MSVSSOLUTIONSUFFIX will be defined to the correct value (see example below).

variant: The name of this particular variant, or a list of variant names (the latter is only supported for MSVS 7 solutions). These are typically things like "Debug" or "Release", but really can be anything you want. For MSVS 7 they may also specify target platform, like this "Debug|Xbox". Default platform is Win32.

projects: A list of project file names, or Project nodes returned by calls to the MSVSProject() Builder, to be placed into the solution file. It should be noted that these file names are NOT added to the $SOURCES environment variable in form of files, but rather as strings. This is because they represent file names to be added to the solution file, not the source files used to build the solution file.

(NOTE: Currently only one project is supported per solution.)

Example Usage:

env.MSVSSolution(target = 'Bar' + env['MSVSSOLUTIONSUFFIX'],
                 projects = ['bar' + env['MSVSPROJECTSUFFIX']],
                 variant = 'Release')

Object()

env.Object()

A synonym for the StaticObject() builder method.

PCH()

env.PCH()

Builds a Microsoft Visual C++ precompiled header. Calling this builder method returns a list of two targets: the PCH as the first element, and the object file as the second element. Normally the object file is ignored. This builder method is only provided when Microsoft Visual C++ is being used as the compiler. The PCH builder method is generally used in conjuction with the PCH construction variable to force object files to use the precompiled header:

env['PCH'] = env.PCH('StdAfx.cpp')[0]

PDF()

env.PDF()

Builds a .pdf file from a .dvi input file (or, by extension, a .tex, .ltx, or .latex input file). The suffix specified by the $PDFSUFFIX construction variable (.pdf by default) is added automatically to the target if it is not already present. Example:

# builds from aaa.tex
env.PDF(target = 'aaa.pdf', source = 'aaa.tex')
# builds bbb.pdf from bbb.dvi
env.PDF(target = 'bbb', source = 'bbb.dvi')

PostScript()

env.PostScript()

Builds a .ps file from a .dvi input file (or, by extension, a .tex, .ltx, or .latex input file). The suffix specified by the $PSSUFFIX construction variable (.ps by default) is added automatically to the target if it is not already present. Example:

# builds from aaa.tex
env.PostScript(target = 'aaa.ps', source = 'aaa.tex')
# builds bbb.ps from bbb.dvi
env.PostScript(target = 'bbb', source = 'bbb.dvi')

Program()

env.Program()

Builds an executable given one or more object files or C, C++, D, or Fortran source files. If any C, C++, D or Fortran source files are specified, then they will be automatically compiled to object files using the Object() builder method; see that builder method's description for a list of legal source file suffixes and how they are interpreted. The target executable file prefix (specified by the $PROGPREFIX construction variable; nothing by default) and suffix (specified by the $PROGSUFFIX construction variable; by default, .exe on Windows systems, nothing on POSIX systems) are automatically added to the target if not already present. Example:

env.Program(target = 'foo', source = ['foo.o', 'bar.c', 'baz.f'])

RES()

env.RES()

Builds a Microsoft Visual C++ resource file. This builder method is only provided when Microsoft Visual C++ or MinGW is being used as the compiler. The .res (or .o for MinGW) suffix is added to the target name if no other suffix is given. The source file is scanned for implicit dependencies as though it were a C file. Example:

env.RES('resource.rc')

RMIC()

env.RMIC()

Builds stub and skeleton class files for remote objects from Java .class files. The target is a directory relative to which the stub and skeleton class files will be written. The source can be the names of .class files, or the objects return from the Java() builder method.

If the construction variable $JAVACLASSDIR is set, either in the environment or in the call to the RMIC() builder method itself, then the value of the variable will be stripped from the beginning of any .class file names.

classes = env.Java(target = 'classdir', source = 'src')
env.RMIC(target = 'outdir1', source = classes)

env.RMIC(target = 'outdir2',
         source = ['package/foo.class', 'package/bar.class'])

env.RMIC(target = 'outdir3',
         source = ['classes/foo.class', 'classes/bar.class'],
         JAVACLASSDIR = 'classes')

RPCGenClient()

env.RPCGenClient()

Generates an RPC client stub (_clnt.c) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif_clnt.c
env.RPCGenClient('src/rpcif.x')

RPCGenHeader()

env.RPCGenHeader()

Generates an RPC header (.h) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif.h
env.RPCGenHeader('src/rpcif.x')

RPCGenService()

env.RPCGenService()

Generates an RPC server-skeleton (_svc.c) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif_svc.c
env.RPCGenClient('src/rpcif.x')

RPCGenXDR()

env.RPCGenXDR()

Generates an RPC XDR routine (_xdr.c) file from a specified RPC (.x) source file. Because rpcgen only builds output files in the local directory, the command will be executed in the source file's directory by default.

# Builds src/rpcif_xdr.c
env.RPCGenClient('src/rpcif.x')

SharedLibrary()

env.SharedLibrary()

Builds a shared library (.so on a POSIX system, .dll on Windows) given one or more object files or C, C++, D or Fortran source files. If any source files are given, then they will be automatically compiled to object files. The static library prefix and suffix (if any) are automatically added to the target. The target library file prefix (specified by the $SHLIBPREFIX construction variable; by default, lib on POSIX systems, nothing on Windows systems) and suffix (specified by the $SHLIBSUFFIX construction variable; by default, .dll on Windows systems, .so on POSIX systems) are automatically added to the target if not already present. Example:

env.SharedLibrary(target = 'bar', source = ['bar.c', 'foo.o'])

On Windows systems, the SharedLibrary() builder method will always build an import (.lib) library in addition to the shared (.dll) library, adding a .lib library with the same basename if there is not already a .lib file explicitly listed in the targets.

Any object files listed in the source must have been built for a shared library (that is, using the SharedObject() builder method). scons will raise an error if there is any mismatch.

On Windows systems, specifying register=1 will cause the .dll to be registered after it is built using REGSVR32. The command that is run ("regsvr32" by default) is determined by $REGSVR construction variable, and the flags passed are determined by $REGSVRFLAGS. By default, $REGSVRFLAGS includes the /s option, to prevent dialogs from popping up and requiring user attention when it is run. If you change $REGSVRFLAGS, be sure to include the /s option. For example,

env.SharedLibrary(target = 'bar',
                  source = ['bar.cxx', 'foo.obj'],
                  register=1)

will register bar.dll as a COM object when it is done linking it.

SharedObject()

env.SharedObject()

Builds an object file for inclusion in a shared library. Source files must have one of the same set of extensions specified above for the StaticObject() builder method. On some platforms building a shared object requires additional compiler option (e.g. -fPIC for gcc) in addition to those needed to build a normal (static) object, but on some platforms there is no difference between a shared object and a normal (static) one. When there is a difference, SCons will only allow shared objects to be linked into a shared library, and will use a different suffix for shared objects. On platforms where there is no difference, SCons will allow both normal (static) and shared objects to be linked into a shared library, and will use the same suffix for shared and normal (static) objects. The target object file prefix (specified by the $SHOBJPREFIX construction variable; by default, the same as $OBJPREFIX) and suffix (specified by the $SHOBJSUFFIX construction variable) are automatically added to the target if not already present. Examples:

env.SharedObject(target = 'ddd', source = 'ddd.c')
env.SharedObject(target = 'eee.o', source = 'eee.cpp')
env.SharedObject(target = 'fff.obj', source = 'fff.for')

Note that the source files will be scanned according to the suffix mappings in the SourceFileScanner object. See the section "Scanner Objects," below, for a more information.

StaticLibrary()

env.StaticLibrary()

Builds a static library given one or more object files or C, C++, D or Fortran source files. If any source files are given, then they will be automatically compiled to object files. The static library prefix and suffix (if any) are automatically added to the target. The target library file prefix (specified by the $LIBPREFIX construction variable; by default, lib on POSIX systems, nothing on Windows systems) and suffix (specified by the $LIBSUFFIX construction variable; by default, .lib on Windows systems, .a on POSIX systems) are automatically added to the target if not already present. Example:

env.StaticLibrary(target = 'bar', source = ['bar.c', 'foo.o'])

Any object files listed in the source must have been built for a static library (that is, using the StaticObject() builder method). scons will raise an error if there is any mismatch.

StaticObject()

env.StaticObject()

Builds a static object file from one or more C, C++, D, or Fortran source files. Source files must have one of the following extensions:

  .asm    assembly language file
  .ASM    assembly language file
  .c      C file
  .C      Windows:  C file
          POSIX:  C++ file
  .cc     C++ file
  .cpp    C++ file
  .cxx    C++ file
  .cxx    C++ file
  .c++    C++ file
  .C++    C++ file
  .d      D file
  .f      Fortran file
  .F      Windows:  Fortran file
          POSIX:  Fortran file + C pre-processor
  .for    Fortran file
  .FOR    Fortran file
  .fpp    Fortran file + C pre-processor
  .FPP    Fortran file + C pre-processor
  .m      Object C file
  .mm     Object C++ file
  .s      assembly language file
  .S      Windows:  assembly language file
          POSIX:  assembly language file + C pre-processor
  .spp    assembly language file + C pre-processor
  .SPP    assembly language file + C pre-processor

The target object file prefix (specified by the $OBJPREFIX construction variable; nothing by default) and suffix (specified by the $OBJSUFFIX construction variable; .obj on Windows systems, .o on POSIX systems) are automatically added to the target if not already present. Examples:

env.StaticObject(target = 'aaa', source = 'aaa.c')
env.StaticObject(target = 'bbb.o', source = 'bbb.c++')
env.StaticObject(target = 'ccc.obj', source = 'ccc.f')

Note that the source files will be scanned according to the suffix mappings in SourceFileScanner object. See the section "Scanner Objects," below, for a more information.

Tar()

env.Tar()

Builds a tar archive of the specified files and/or directories. Unlike most builder methods, the Tar() builder method may be called multiple times for a given target; each additional call adds to the list of entries that will be built into the archive. Any source directories will be scanned for changes to any on-disk files, regardless of whether or not scons knows about them from other Builder or function calls.

env.Tar('src.tar', 'src')

# Create the stuff.tar file.
env.Tar('stuff', ['subdir1', 'subdir2'])
# Also add "another" to the stuff.tar file.
env.Tar('stuff', 'another')

# Set TARFLAGS to create a gzip-filtered archive.
env = Environment(TARFLAGS = '-c -z')
env.Tar('foo.tar.gz', 'foo')

# Also set the suffix to .tgz.
env = Environment(TARFLAGS = '-c -z',
                  TARSUFFIX = '.tgz')
env.Tar('foo')

TypeLibrary()

env.TypeLibrary()

Builds a Windows type library (.tlb) file from an input IDL file (.idl). In addition, it will build the associated inteface stub and proxy source files, naming them according to the base name of the .idl file. For example,

env.TypeLibrary(source="foo.idl")

Will create foo.tlb, foo.h, foo_i.c, foo_p.c and foo_data.c files.

Uic()

env.Uic()

Builds a header file, an implementation file and a moc file from an ui file. and returns the corresponding nodes in the above order. This builder is only available after using the tool 'qt'. Note: you can specify .ui files directly as source files to the Program(), Library()andSharedLibrary()builders without using this builder. Using this builder lets you override the standard naming conventions (be careful: prefixes are always prepended to names of built files; if you don't want prefixes, you may set them to ``). See the $QTDIR variable for more information. Example:

env.Uic('foo.ui') # -> ['foo.h', 'uic_foo.cc', 'moc_foo.cc']
env.Uic(target = Split('include/foo.h gen/uicfoo.cc gen/mocfoo.cc'),
        source = 'foo.ui') # -> ['include/foo.h', 'gen/uicfoo.cc', 'gen/mocfoo.cc']

Zip()

env.Zip()

Builds a zip archive of the specified files and/or directories. Unlike most builder methods, the Zip() builder method may be called multiple times for a given target; each additional call adds to the list of entries that will be built into the archive. Any source directories will be scanned for changes to any on-disk files, regardless of whether or not scons knows about them from other Builder or function calls.

env.Zip('src.zip', 'src')

# Create the stuff.zip file.
env.Zip('stuff', ['subdir1', 'subdir2'])
# Also add "another" to the stuff.tar file.
env.Zip('stuff', 'another')

All targets of builder methods automatically depend on their sources. An explicit dependency can be specified using the Depends method of a construction environment (see below).

In addition, scons automatically scans source files for various programming languages, so the dependencies do not need to be specified explicitly. By default, SCons can C source files, C++ source files, Fortran source files with .F (POSIX systems only), .fpp, or .FPP file extensions, and assembly language files with .S (POSIX systems only), .spp, or .SPP files extensions for C preprocessor dependencies. SCons also has default support for scanning D source files, You can also write your own Scanners to add support for additional source file types. These can be added to the default Scanner object used by the Object() StaticObject() and SharedObject() Builders by adding them to the SourceFileScanner object as follows:

See the section "Scanner Objects," below, for a more information about defining your own Scanner objects.

Methods and Functions to Do Things

Usually, a construction environment method and global function with the same name both exist so that you don't have to remember whether to a specific bit of functionality must be called with or without a construction environment. In the following list, if you call something as a global function it looks like:

Function(arguments)

env.Function(arguments)

Global functions may be called from custom Python modules that you import into an SConscript file by adding the following to the Python module:

from SCons.Script import *

Except where otherwise noted, the same-named construction environment method and global function provide the exact same functionality. The only difference is that, where appropriate, calling the functionality through a construction environment will substitute construction variables into any supplied strings. For example:

env = Environment(FOO = 'foo')
Default('$FOO')
env.Default('$FOO')

Construction environment methods and global functions supported by scons include:

Action(action, [strfunction, varlist])

env.Action(action, [strfunction, varlist])

Creates an Action object for the specified action. See the section "Action Objects," below, for a complete explanation of the arguments and behavior.

Note that the env.Action() form of the invocation will expand construction variables in any arguments strings, including the action argument, at the time it is called using the construction variables in the env construction environment through which env.Action() was called. The Action() form delays all variable expansion until the Action object is actually used.

AddPostAction(target, action)

env.AddPostAction(target, action)

Arranges for the specified action to be performed after the specified target has been built. The specified action(s) may be an Action object, or anything that can be converted into an Action object (see below).

AddPreAction(target, action)

env.AddPreAction(target, action)

Arranges for the specified action to be performed before the specified target is built. The specified action(s) may be an Action object, or anything that can be converted into an Action object (see below).

Alias(alias, [targets, [action]])

env.Alias(alias, [targets, [action]])

Creates one or more phony targets that expand to one or more other targets. An optional action (command) or list of actions can be specified that will be executed whenever the any of the alias targets are out-of-date. Returns the Node object representing the alias, which exists outside of any file system. This Node object, or the alias name, may be used as a dependency of any other target, including another alias. Alias can be called multiple times for the same alias to add additional targets to the alias, or additional actions to the list for this alias.

Alias('install')
Alias('install', '/usr/bin')
Alias(['install', 'install-lib'], '/usr/local/lib')

env.Alias('install', ['/usr/local/bin', '/usr/local/lib'])
env.Alias('install', ['/usr/local/man'])

env.Alias('update', ['file1', 'file2'], "update_database $SOURCES")

AllowSubstExceptions([exception, ...])

Specifies the exceptions that will be allowed when expanding construction variables. By default, any construction variable expansions that generate a NameError or IndexError exception will expand to a '' (a null string) and not cause scons to fail. All exceptions not in the specified list will generate an error message and terminate processing.

If AllowSubstExceptions is called multiple times, each call completely overwrites the previous list of allowed exceptions. Example:

# Requires that all construction variable names exist.
# (You may wish to do this if you want to enforce strictly
# that all construction variables must be defined before use.)
AllowSubstExceptions()

# Also allow a string containing a zero-division expansion
# like '${1 / 0}' to evalute to ''.
AllowSubstExceptions(IndexError, NameError, ZeroDivisionError)

AlwaysBuild(target, ...)

env.AlwaysBuild(target, ...)

Marks each given target so that it is always assumed to be out of date, and will always be rebuilt if needed. Note, however, that AlwaysBuild() does not add its target(s) to the default target list, so the targets will only be built if they are specified on the command line, or are a dependent of a target specified on the command line--but they will always be built if so specified. Multiple targets can be passed in to a single call to AlwaysBuild().

env.Append(key=val, [...])

Appends the specified keyword arguments to the end of construction variables in the environment. If the Environment does not have the specified construction variable, it is simply added to the environment. If the values of the construction variable and the keyword argument are the same type, then the two values will be simply added together. Otherwise, the construction variable and the value of the keyword argument are both coerced to lists, and the lists are added together. (See also the Prepend method, below.)

env.Append(CCFLAGS = ' -g', FOO = ['foo.yyy'])

env.AppendENVPath(name, newpath, [envname, sep])

This appends new path elements to the given path in the specified external environment (ENV by default). This will only add any particular path once (leaving the last one it encounters and ignoring the rest, to preserve path order), and to help assure this, will normalize all paths (using os.path.normpath and os.path.normcase). This can also handle the case where the given old path variable is a list instead of a string, in which case a list will be returned instead of a string. Example:

print 'before:',env['ENV']['INCLUDE']
include_path = '/foo/bar:/foo'
env.AppendENVPath('INCLUDE', include_path)
print 'after:',env['ENV']['INCLUDE']

yields:
before: /foo:/biz
after: /biz:/foo/bar:/foo

env.AppendUnique(key=val, [...])

Appends the specified keyword arguments to the end of construction variables in the environment. If the Environment does not have the specified construction variable, it is simply added to the environment. If the construction variable being appended to is a list, then any value(s) that already exist in the construction variable will not be added again to the list.

env.AppendUnique(CCFLAGS = '-g', FOO = ['foo.yyy'])

env.BitKeeper()

A factory function that returns a Builder object to be used to fetch source files using BitKeeper. The returned Builder is intended to be passed to the SourceCode function.

env.SourceCode('.', env.BitKeeper())

BuildDir(build_dir, src_dir, [duplicate])

env.BuildDir(build_dir, src_dir, [duplicate])

This specifies a build directory build_dir in which to build all derived files that would normally be built under src_dir. Multiple build directories can be set up for multiple build variants, for example. src_dir must be underneath the SConstruct file's directory, and build_dir may not be underneath the src_dir .

The default behavior is for scons to duplicate all of the files in the tree underneath src_dir into build_dir, and then build the derived files within the copied tree. (The duplication is performed by linking or copying, depending on the platform; see also the --duplicate option.) This guarantees correct builds regardless of whether intermediate source files are generated during the build, where preprocessors or other scanners search for included files, or whether individual compilers or other invoked tools are hard-coded to put derived files in the same directory as source files.

This behavior of making a complete copy of the source tree may be disabled by setting duplicate to 0. This will cause scons to invoke Builders using the path names of source files in src_dir and the path names of derived files within build_dir. This is always more efficient than duplicate=1, and is usually safe for most builds. Specifying duplicate=0, however, may cause build problems if source files are generated during the build, if any invoked tools are hard-coded to put derived files in the same directory as the source files.

Note that specifying a BuildDir works most naturally with a subsidiary SConscript file in the source directory. However, you would then call the subsidiary SConscript file not in the source directory, but in the build_dir , as if scons had made a virtual copy of the source tree regardless of the value of duplicate. This is how you tell scons which variant of a source tree to build. For example:

BuildDir('build-variant1', 'src')
SConscript('build-variant1/SConscript')
BuildDir('build-variant2', 'src')
SConscript('build-variant2/SConscript')

See also the SConscript() function, described below, for another way to specify a build directory in conjunction with calling a subsidiary SConscript file.)

Builder(action, [arguments])

env.Builder(action, [arguments])

Creates a Builder object for the specified action. See the section "Builder Objects," below, for a complete explanation of the arguments and behavior.

Note that the env.Builder() form of the invocation will expand construction variables in any arguments strings, including the action argument, at the time it is called using the construction variables in the env construction environment through which env.Builder() was called. The Builder() form delays all variable expansion until after the Builder object is actually called.

CacheDir(cache_dir)

env.CacheDir(cache_dir)

Specifies that scons will maintain a cache of derived files in cache_dir . The derived files in the cache will be shared among all the builds using the same CacheDir() call.

When a CacheDir() is being used and scons finds a derived file that needs to be rebuilt, it will first look in the cache to see if a derived file has already been built from identical input files and an identical build action (as incorporated into the MD5 build signature). If so, scons will retrieve the file from the cache. If the derived file is not present in the cache, scons will rebuild it and then place a copy of the built file in the cache (identified by its MD5 build signature), so that it may be retrieved by other builds that need to build the same derived file from identical inputs.

Use of a specified CacheDir() may be disabled for any invocation by using the --cache-disable option.

If the --cache-force option is used, scons will place a copy of all derived files in the cache, even if they already existed and were not built by this invocation. This is useful to populate a cache the first time CacheDir() is added to a build, or after using the --cache-disable option.

When using CacheDir(), scons will report, "Retrieved `file' from cache," unless the --cache-show option is being used. When the --cache-show option is used, scons will print the action that would have been used to build the file, without any indication that the file was actually retrieved from the cache. This is useful to generate build logs that are equivalent regardless of whether a given derived file has been built in-place or retrieved from the cache.

The NoCache() method can be used to disable caching of specific files. This can be useful if inputs and/or outputs of some tool are impossible to predict or prohibitively large.

Clean(targets, files_or_dirs)

env.Clean(targets, files_or_dirs)

This specifies a list of files or directories which should be removed whenever the targets are specified with the -c command line option. The specified targets may be a list or an individual target. Multiple calls to Clean() are legal, and create new targets or add files and directories to the clean list for the specified targets.

Multiple files or directories should be specified either as separate arguments to the Clean() method, or as a list. Clean() will also accept the return value of any of the construction environment Builder methods. Examples:

The related NoClean() function overrides calling Clean() for the same target, and any targets passed to both functions will not be removed by the -c option.

Examples:

Clean('foo', ['bar', 'baz'])
Clean('dist', env.Program('hello', 'hello.c'))
Clean(['foo', 'bar'], 'something_else_to_clean')

Command(target, source, action, [key=val, ...])

env.Command(target, source, action, [key=val, ...])

Executes a specific action (or list of actions) to build a target file or files. This is more convenient than defining a separate Builder object for a single special-case build.

As a special case, the source_scanner keyword argument can be used to specify a Scanner object that will be used to scan the sources. (The global DirScanner object can be used if any of the sources will be directories that must be scanned on-disk for changes to files that aren't already specified in other Builder of function calls.)

Any other keyword arguments specified override any same-named existing construction variables.

An action can be an external command, specified as a string, or a callable Python object; see "Action Objects," below, for more complete information. Also note that a string specifying an external command may be preceded by an @ (at-sign) to suppress printing the command in question, or by a - (hyphen) to ignore the exit status of the external command. Examples:

env.Command('foo.out', 'foo.in',
            "$FOO_BUILD < $SOURCES > $TARGET")

env.Command('bar.out', 'bar.in',
            ["rm -f $TARGET",
             "$BAR_BUILD < $SOURCES > $TARGET"],
            ENV = {'PATH' : '/usr/local/bin/'})

def rename(env, target, source):
    import os
    os.rename('.tmp', str(target[0]))

env.Command('baz.out', 'baz.in',
            ["$BAZ_BUILD < $SOURCES > .tmp",
             rename ])

Note that the Command() function will usually assume, by default, that the specified targets and/or sources are Files, if no other part of the configuration identifies what type of entry it is. If necessary, you can explicitly specify that targets or source nodes should be treated as directoriese by using the Dir() or env.Dir() functions:

env.Command('ddd.list', Dir('ddd'), 'ls -l $SOURCE > $TARGET')

env['DISTDIR'] = 'destination/directory'
env.Command(env.Dir('$DISTDIR')), None, make_distdir)

(Also note that SCons will usually automatically create any directory necessary to hold a target file, so you normally don't need to create directories by hand.)

Configure(env, [custom_tests, conf_dir, log_file, config_h])

env.Configure([custom_tests, conf_dir, log_file, config_h])

Creates a Configure object for integrated functionality similar to GNU autoconf. See the section "Configure Contexts," below, for a complete explanation of the arguments and behavior.

env.Clone([key=val, ...])

Return a separate copy of a construction environment. If there are any keyword arguments specified, they are added to the returned copy, overwriting any existing values for the keywords.

env2 = env.Clone()
env3 = env.Clone(CCFLAGS = '-g')

Additionally, a list of tools and a toolpath may be specified, as in the Environment constructor:

def MyTool(env): env['FOO'] = 'bar'
env4 = env.Clone(tools = ['msvc', MyTool])

env.Copy([key=val, ...])

A synonym for env.Clone(). (This will probably be officially deprecated some day.)

env.CVS(repository, module)

A factory function that returns a Builder object to be used to fetch source files from the specified CVS repository. The returned Builder is intended to be passed to the SourceCode function.

The optional specified module will be added to the beginning of all repository path names; this can be used, in essence, to strip initial directory names from the repository path names, so that you only have to replicate part of the repository directory hierarchy in your local build directory:

# Will fetch foo/bar/src.c
# from /usr/local/CVSROOT/foo/bar/src.c.
env.SourceCode('.', env.CVS('/usr/local/CVSROOT'))

# Will fetch bar/src.c
# from /usr/local/CVSROOT/foo/bar/src.c.
env.SourceCode('.', env.CVS('/usr/local/CVSROOT', 'foo'))

# Will fetch src.c
# from /usr/local/CVSROOT/foo/bar/src.c.
env.SourceCode('.', env.CVS('/usr/local/CVSROOT', 'foo/bar'))

Default(targets)

env.Default(targets)

This specifies a list of default targets, which will be built by scons if no explicit targets are given on the command line. Multiple calls to Default() are legal, and add to the list of default targets.

Multiple targets should be specified as separate arguments to the Default() method, or as a list. Default() will also accept the Node returned by any of a construction environment's builder methods. Examples:

Default('foo', 'bar', 'baz')
env.Default(['a', 'b', 'c'])
hello = env.Program('hello', 'hello.c')
env.Default(hello)

An argument to Default() of None will clear all default targets. Later calls to Default() will add to the (now empty) default-target list like normal.

The current list of targets added using the Default() function or method is available in the DEFAULT_TARGETS list; see below.

DefaultEnvironment([args])

Creates and returns a default construction environment object. This construction environment is used internally by SCons in order to execute many of the global functions in this list, and to fetch source files transparently from source code management systems.

Depends(target, dependency)

env.Depends(target, dependency)

Specifies an explicit dependency; the target file(s) will be rebuilt whenever the dependency file(s) has changed. This should only be necessary for cases where the dependency is not caught by a Scanner for the file.

env.Depends('foo', 'other-input-file-for-foo')

env.Dictionary([vars])

Returns a dictionary object containing copies of all of the construction variables in the environment. If there are any variable names specified, only the specified construction variables are returned in the dictionary.

dict = env.Dictionary()
cc_dict = env.Dictionary('CC', 'CCFLAGS', 'CCCOM')

Dir(name, [directory])

env.Dir(name, [directory])

This returns a Directory Node, an object that represents the specified directory name. name can be a relative or absolute path. directory is an optional directory that will be used as the parent directory. If no directory is specified, the current script's directory is used as the parent.

Directory Nodes can be used anywhere you would supply a string as a directory name to a Builder method or function. Directory Nodes have attributes and methods that are useful in many situations; see "File and Directory Nodes," below.

env.Dump([key])

Returns a pretty printable representation of the environment. key, if not None, should be a string containing the name of the variable of interest.

This SConstruct:

env=Environment()
print env.Dump('CCCOM')

will print:

env=Environment()
print env.Dump()

will print:

{ 'AR': 'ar',
  'ARCOM': '$AR $ARFLAGS $TARGET $SOURCESRANLIB $RANLIBFLAGS $TARGET',
  'ARFLAGS': ['r'],
  'AS': 'as',
  'ASCOM': '$AS $ASFLAGS -o $TARGET $SOURCES',
  'ASFLAGS': [],
  ...

EnsurePythonVersion(major, minor)

env.EnsurePythonVersion(major, minor)

Ensure that the Python version is at least major.minor. This function will print out an error message and exit SCons with a non-zero exit code if the actual Python version is not late enough.

EnsurePythonVersion(2,2)

EnsureSConsVersion(major, minor, [revision])

env.EnsureSConsVersion(major, minor, [revision])

Ensure that the SCons version is at least major.minor, or major.minor.revision. if revision is specified. This function will print out an error message and exit SCons with a non-zero exit code if the actual SCons version is not late enough.

EnsureSConsVersion(0,14)

EnsureSConsVersion(0,96,90)

Environment([key=value, ...])

env.Environment([key=value, ...])

Return a new construction environment initialized with the specified key=value pairs.

Execute(action, [strfunction, varlist])

env.Execute(action, [strfunction, varlist])

Executes an Action object. The specified action may be an Action object (see the section "Action Objects," below, for a complete explanation of the arguments and behavior), or it may be a command-line string, list of commands, or executable Python function, each of which will be converted into an Action object and then executed. The exit value of the command or return value of the Python function will be returned.

Exit([value])

env.Exit([value])

This tells scons to exit immediately with the specified value. A default exit value of 0 (zero) is used if no value is specified.

Export(vars)

env.Export(vars)

This tells scons to export a list of variables from the current SConscript file to all other SConscript files. The exported variables are kept in a global collection, so subsequent calls to Export() will over-write previous exports that have the same name. Multiple variable names can be passed to Export() as separate arguments or as a list. A dictionary can be used to map variables to a different name when exported. Both local variables and global variables can be exported. Examples:

env = Environment()
# Make env available for all SConscript files to Import().
Export("env")

package = 'my_name'
# Make env and package available for all SConscript files:.
Export("env", "package")

# Make env and package available for all SConscript files:
Export(["env", "package"])

# Make env available using the name debug:.
Export({"debug":env})

Note that the SConscript() function supports an exports argument that makes it easier to to export a variable or set of variables to a single SConscript file. See the description of the SConscript() function, below.

File(name, [directory])

env.File(name, [directory])

This returns a File Node, an object that represents the specified file name. name can be a relative or absolute path. directory is an optional directory that will be used as the parent directory.

File Nodes can be used anywhere you would supply a string as a file name to a Builder method or function. File Nodes have attributes and methods that are useful in many situations; see "File and Directory Nodes," below.

FindFile(file, dirs)

env.FindFile(file, dirs)

Search for file in the path specified by dirs. file may be a list of file names or a single file name. In addition to searching for files that exist in the filesytem, this function also searches for derived files that have not yet been built.

foo = env.FindFile('foo', ['dir1', 'dir2'])

FindPathDirs(variable)

Returns a function (actually a callable Python object) intended to be used as the path_function of a Scanner object. The returned object will look up the specified variable in a construction environment and treat the construction variable's value as a list of directory paths that should be searched (like CPPPATH, LIBPATH, etc.).

Note that use of FindPathDirs() is generally preferable to writing your own path_function for the following reasons: 1) The returned list will contain all appropriate directories found in source trees (when BuildDir() is used) or in code repositories (when Repository() or the -Y option are used). 2) scons will identify expansions of variable that evaluate to the same list of directories as, in fact, the same list, and avoid re-scanning the directories for files, when possible.

Example:

def my_scan(node, env, path, arg):
    # Code to scan file contents goes here...
    return include_files

scanner = Scanner(name = 'myscanner',
                  function = my_scan,
                  path_function = FindPathDirs('MYPATH'))

Flatten(sequence)

env.Flatten(sequence)

Takes a sequence (that is, a Python list or tuple) that may contain nested sequences and returns a flattened list containing all of the individual elements in any sequence. This can be helpful for collecting the lists returned by calls to Builders; other Builders will automatically flatten lists specified as input, but direct Python manipulation of these lists does not:

foo = Object('foo.c')
bar = Object('bar.c')

# Because `foo' and `bar' are lists returned by the Object() Builder,
# `objects' will be a list containing nested lists:
objects = ['f1.o', foo, 'f2.o', bar, 'f3.o']

# Passing such a list to another Builder is all right because
# the Builder will flatten the list automatically:
Program(source = objects)

# If you need to manipulate the list directly using Python, you need to
# call Flatten() yourself, or otherwise handle nested lists:
for object in Flatten(objects):
    print str(object)

GetBuildPath(file, [...])

env.GetBuildPath(file, [...])

Returns the scons path name (or names) for the specified file (or files). The specified file or files may be scons Nodes or strings representing path names.

GetLaunchDir()

env.GetLaunchDir()

Returns the absolute path name of the directory from which scons was initially invoked. This can be useful when using the -u, -U or -D options, which internally change to the directory in which the SConstruct file is found.

GetOption(name)

env.GetOption(name)

This function provides a way to query a select subset of the scons command line options from a SConscript file. See SetOption() for a description of the options available.

Help(text)

env.Help(text)

This specifies help text to be printed if the -h argument is given to scons. If Help is called multiple times, the text is appended together in the order that Help is called.

Ignore(target, dependency)

env.Ignore(target, dependency)

The specified dependency file(s) will be ignored when deciding if the target file(s) need to be rebuilt.

env.Ignore('foo', 'foo.c')
env.Ignore('bar', ['bar1.h', 'bar2.h'])

Import(vars)

env.Import(vars)

This tells scons to import a list of variables into the current SConscript file. This will import variables that were exported with Export() or in the exports argument to SConscript(). Variables exported by SConscript() have precedence. Multiple variable names can be passed to Import() as separate arguments or as a list. The variable "*" can be used to import all variables. Examples:

Import("env")
Import("env", "variable")
Import(["env", "variable"])
Import("*")

Install(dir, source)

env.Install(dir, source)

Installs one or more source files or directories in a destination directory dir. The names of the specified source files or directories remain the same within the destination directory.

env.Install(dir = '/usr/local/bin', source = ['foo', 'bar'])

InstallAs(target, source)

env.InstallAs(target, source)

Installs one or more source files or directories to specific names, allowing changing a file or directory name as part of the installation. It is an error if the target and source arguments list different numbers of files or directories.

env.InstallAs(target = '/usr/local/bin/foo',
              source = 'foo_debug')
env.InstallAs(target = ['../lib/libfoo.a', '../lib/libbar.a'],
              source = ['libFOO.a', 'libBAR.a'])

Literal(string)

env.Literal(string)

The specified string will be preserved as-is and not have construction variables expanded.

Local(targets)

env.Local(targets)

The specified targets will have copies made in the local tree, even if an already up-to-date copy exists in a repository. Returns a list of the target Node or Nodes.

env.MergeFlags(arg, [unique])

Merges the specified arg values to the construction envrionment's construction variables. If the arg argument is not a dictionary, it is converted to one by calling env.ParseFlags() on the argument before the values are merged. Note that arg must be a single value, so multiple strings must be passed in as a list, not as separate arguments to env.MergeFlags().

By default, duplicate values are eliminated; you can, however, specify unique=0 to allow duplicate values to be added. When eliminating duplicate values, any construction variables that end with the string PATH keep the left-most unique value. All other construction variables keep the right-most unique value.

Examples:

# Add an optimization flag to $CCFLAGS.
env.MergeFlags('-O3')

# Combine the flags returned from running pkg-config with an optimization
# flag and merge the result into the construction variables.
env.MergeFlags(['!pkg-config gtk+-2.0 --cflags', '-O3'])

env.MergeFlags(['-O3',
               '!pkg-config gtk+-2.0 --cflags --libs',
               '!pkg-config libpng12 --cflags --libs'])

NoCache(target, ...)

env.NoCache(target, ...)

Specifies a list of files which should not be cached whenever the CacheDir() method has been activated. The specified targets may be a list or an individual target.

Multiple files should be specified either as separate arguments to the NoCache() method, or as a list. NoCache() will also accept the return value of any of the construction environment Builder methods.

Calling NoCache() on directories and other non-File Node types has no effect because only File Nodes are cached.

Examples:

NoCache('foo.elf')
NoCache(env.Program('hello', 'hello.c'))

NoClean(target, ...)

env.NoClean(target, ...)

Specifies a list of files or directories which should not be removed whenever the targets (or their dependencies) are specified with the -c command line option. The specified targets may be a list or an individual target. Multiple calls to NoClean() are legal, and prevent each specified target from being removed by calls to the -c option.

Multiple files or directories should be specified either as separate arguments to the NoClean() method, or as a list. NoClean() will also accept the return value of any of the construction environment Builder methods.

Calling NoClean() for a target overrides calling Clean() for the same target, and any targets passed to both functions will not be removed by the -c option.

Examples:

NoClean('foo.elf')
NoClean(env.Program('hello', 'hello.c'))

env.ParseConfig(command, [function, unique])

Calls the specified function to modify the environment as specified by the output of command . The default function is env.MergeFlags(), which expects the output of a typical *-config command (for example, gtk-config) and adds the options to the appropriate construction variables. By default, duplicate values are not added to any construction variables; you can specify unique=0 to allow duplicate values to be added.

Interpreted options and the construction variables they affect are as specified for the env.ParseFlags() method (which thie method calls). See that method's description, below, for a table of options and construction variables.

ParseDepends(filename, [must_exist, only_one])

env.ParseDepends(filename, [must_exist, only_one])

Parses the contents of the specified filename as a list of dependencies in the style of Make or mkdep, and explicitly establishes all of the listed dependencies.

By default, it is not an error if the specified filename does not exist. The optional must_exist argument may be set to a non-zero value to have scons throw an exception and generate an error if the file does not exist, or is otherwise inaccessible.

The optional only_one argument may be set to a non-zero value to have scons thrown an exception and generate an error if the file contains dependency information for more than one target. This can provide a small sanity check for files intended to be generated by, for example, the gcc -M flag, which should typically only write dependency information for one output file into a corresponding .d file.

The filename and all of the files listed therein will be interpreted relative to the directory of the SConscript file which calls the ParseDepends function.

env.ParseFlags(flags, ...)

Parses one or more strings containing typical command-line flags for GCC tool chains and returns a dictionary with the flag values separated into the appropriate SCons construction variables. This is intended as a companion to the env.MergeFlags() method, but allows for the values in the returned dictionary to be modified, if necessary, before merging them into the construction environment. (Note that env.MergeFlags() will call this method if its argument is not a dictionary, so it is usually not necessary to call env.ParseFlags() directly unless you want to manipulate the values.)

If the first character in any string is an exclamation mark (!), the rest of the string is executed as a command, and the output from the command is parsed as GCC tool chain command-line flags and added to the resulting dictionary.

Flag values are translated accordig to the prefix found, and added to the following construction variables:

-arch               CCFLAGS, LINKFLAGS
-D                  CPPDEFINES
-framework          FRAMEWORKS
-frameworkdir=      FRAMEWORKPATH
-include            CCFLAGS
-isysroot           CCFLAGS, LINKFLAGS
-I                  CPPPATH
-l                  LIBS
-L                  LIBPATH
-mno-cygwin         CCFLAGS, LINKFLAGS
-mwindows           LINKFLAGS
-pthread            CCFLAGS, LINKFLAGS
-std=               CFLAGS
-Wa,                ASFLAGS, CCFLAGS
-Wl,-rpath=         RPATH
-Wl,-R,             RPATH
-Wl,-R              RPATH
-Wl,                LINKFLAGS
-Wp,                CPPFLAGS
-                   CCFLAGS
+                   CCFLAGS, LINKFLAGS

Any other strings not associated with options are assumed to be the names of libraries and added to the LIBS construction variable.

Examples (all of which produce the same result):

dict = env.ParseFlags('-O2 -Dfoo -Dbar=1')
dict = env.ParseFlags('-O2', '-Dfoo', '-Dbar=1')
dict = env.ParseFlags(['-O2', '-Dfoo -Dbar=1'])
dict = env.ParseFlags('-O2', '!echo -Dfoo -Dbar=1')

env.Perforce()

A factory function that returns a Builder object to be used to fetch source files from the Perforce source code management system. The returned Builder is intended to be passed to the SourceCode function:

env.SourceCode('.', env.Perforce())

Perforce uses a number of external environment variables for its operation. Consequently, this function adds the following variables from the user's external environment to the construction environment's ENV dictionary: P4CHARSET, P4CLIENT, P4LANGUAGE, P4PASSWD, P4PORT, P4USER, SYSTEMROOT, USER, and USERNAME.

Platform(string)

Returns a callable object that can be used to initialize a construction environment using the platform keyword of the Environment() method:

env = Environment(platform = Platform('win32'))

env.Platform(string)

Applies the callable object for the specified platform string to the environment through which the method was called.

env.Platform('posix')

Note that the win32 platform adds the SYSTEMDRIVE and SYSTEMROOT variables from the user's external environment to the construction environment's ENV dictionary. This is so that any executed commands that use sockets to connect with other systems (such as fetching source files from external CVS repository specifications like :pserver:anonymous@cvs.sourceforge.net:/cvsroot/scons) will work on Windows systems.

Precious(target, ...)

env.Precious(target, ...)

Marks each given target as precious so it is not deleted before it is rebuilt. Normally scons deletes a target before building it. Multiple targets can be passed in to a single call to Precious().

env.Prepend(key=val, [...])

Appends the specified keyword arguments to the beginning of construction variables in the environment. If the Environment does not have the specified construction variable, it is simply added to the environment. If the values of the construction variable and the keyword argument are the same type, then the two values will be simply added together. Otherwise, the construction variable and the value of the keyword argument are both coerced to lists, and the lists are added together. (See also the Append method, above.)

env.Prepend(CCFLAGS = '-g ', FOO = ['foo.yyy'])

env.PrependENVPath(name, newpath, [envname, sep])

This appends new path elements to the given path in the specified external environment (ENV by default). This will only add any particular path once (leaving the first one it encounters and ignoring the rest, to preserve path order), and to help assure this, will normalize all paths (using os.path.normpath and os.path.normcase). This can also handle the case where the given old path variable is a list instead of a string, in which case a list will be returned instead of a string. Example:

print 'before:',env['ENV']['INCLUDE']
include_path = '/foo/bar:/foo'
env.PrependENVPath('INCLUDE', include_path)
print 'after:',env['ENV']['INCLUDE']

yields:
before: /biz:/foo
after: /foo/bar:/foo:/biz

env.PrependUnique(key=val, [...])

Appends the specified keyword arguments to the beginning of construction variables in the environment. If the Environment does not have the specified construction variable, it is simply added to the environment. If the construction variable being appended to is a list, then any value(s) that already exist in the construction variable will not be added again to the list.

env.PrependUnique(CCFLAGS = '-g', FOO = ['foo.yyy'])

env.RCS()

A factory function that returns a Builder object to be used to fetch source files from RCS. The returned Builder is intended to be passed to the SourceCode function:

env.SourceCode('.', env.RCS())

Note that scons will fetch source files from RCS subdirectories automatically, so configuring RCS as demonstrated in the above example should only be necessary if you are fetching from RCS,v files in the same directory as the source files, or if you need to explicitly specify RCS for a specific subdirectory.

env.Replace(key=val, [...])

Replaces construction variables in the Environment with the specified keyword arguments.

env.Replace(CCFLAGS = '-g', FOO = 'foo.xxx')

Repository(directory)

env.Repository(directory)

Specifies that directory is a repository to be searched for files. Multiple calls to Repository() are legal, and each one adds to the list of repositories that will be searched.

To scons, a repository is a copy of the source tree, from the top-level directory on down, which may contain both source files and derived files that can be used to build targets in the local source tree. The canonical example would be an official source tree maintained by an integrator. If the repository contains derived files, then the derived files should have been built using scons, so that the repository contains the necessary signature information to allow scons to figure out when it is appropriate to use the repository copy of a derived file, instead of building one locally.

Note that if an up-to-date derived file already exists in a repository, scons will not make a copy in the local directory tree. In order to guarantee that a local copy will be made, use the Local() method.

Return(vars)

This tells scons what variable(s) to use as the return value(s) of the current SConscript file. These variables will be returned to the "calling" SConscript file as the return value(s) of SConscript(). Multiple variable names should be passed to Return() as a list. Example:

Return("foo")
Return(["foo", "bar"])

Scanner(function, [argument, keys, path_function, node_class, node_factory, scan_check, recursive])

env.Scanner(function, [argument, keys, path_function, node_class, node_factory, scan_check, recursive])

Creates a Scanner object for the specified function. See the section "Scanner Objects," below, for a complete explanation of the arguments and behavior.

env.SCCS()

A factory function that returns a Builder object to be used to fetch source files from SCCS. The returned Builder is intended to be passed to the SourceCode function:

env.SourceCode('.', env.SCCS())

Note that scons will fetch source files from SCCS subdirectories automatically, so configuring SCCS as demonstrated in the above example should only be necessary if you are fetching from s.SCCS files in the same directory as the source files, or if you need to explicitly specify SCCS for a specific subdirectory.

SConscript(scripts, [exports, build_dir, src_dir, duplicate])

env.SConscript(scripts, [exports, build_dir, src_dir, duplicate])

SConscript(dirs=subdirs, [name=script, exports, build_dir, src_dir, duplicate])

env.SConscript(dirs=subdirs, [name=script, exports, build_dir, src_dir, duplicate])

This tells scons to execute one or more subsidiary SConscript (configuration) files. There are two ways to call the SConscript() function.

The first way you can call SConscript() is to explicitly specify one or more scripts as the first argument. A single script may be specified as a string; multiple scripts must be specified as a list (either explicitly or as created by a function like Split()).

The second way you can call SConscript() is to specify a list of (sub)directory names as a dirs=subdirs keyword argument. In this case, scons will, by default, execute a subsidiary configuration file named SConscript in each of the specified directories. You may specify a name other than SConscript by supplying an optional name=script keyword argument.

The optional exports argument provides a list of variable names or a dictionary of named values to export to the script(s). These variables are locally exported only to the specified script(s), and do not affect the global pool of variables used by the Export() function. The subsidiary script(s) must use the Import() function to import the variables.

The optional build_dir argument specifies that all of the target files (for example, object files and executables) that would normally be built in the subdirectory in which script resides should actually be built in build_dir. build_dir is interpreted relative to the directory of the calling SConscript file.

The optional src_dir argument specifies that the source files from which the target files should be built can be found in src_dir. src_dir is interpreted relative to the directory of the calling SConscript file.

By default, scons will link or copy (depending on the platform) all the source files into the build directory. This behavior may be disabled by setting the optional duplicate argument to 0 (it is set to 1 by default), in which case scons will refer directly to the source files in their source directory when building target files. (Setting duplicate=0 is usually safe, and always more efficient than the default of duplicate=1, but it may cause build problems in certain end-cases, such as compiling from source files that are generated by the build.)

Any variables returned by script using Return() will be returned by the call to SConscript().

Examples:

SConscript('subdir/SConscript')
foo = SConscript('sub/SConscript', exports='env')
SConscript('dir/SConscript', exports=['env', 'variable'])
SConscript('src/SConscript', build_dir='build', duplicate=0)
SConscript('bld/SConscript', src_dir='src', exports='env variable')
SConscript(dirs=['sub1', 'sub2'])
SConscript(dirs=['sub3', 'sub4'], name='MySConscript')

SConscriptChdir(value)

env.SConscriptChdir(value)

By default, scons changes its working directory to the directory in which each subsidiary SConscript file lives. This behavior may be disabled by specifying either:

SConscriptChdir(0)
env.SConscriptChdir(0)

in which case scons will stay in the top-level directory while reading all SConscript files. (This may be necessary when building from repositories, when all the directories in which SConscript files may be found don't necessarily exist locally.)

You may enable and disable this ability by calling SConscriptChdir() multiple times:

env = Environment()
SConscriptChdir(0)
SConscript('foo/SConscript')    # will not chdir to foo
env.SConscriptChdir(1)
SConscript('bar/SConscript')    # will chdir to bar

SConsignFile([file,dbm_module])

env.SConsignFile([file,dbm_module])

This tells scons to store all file signatures in the specified database file. If the file name is omitted, .sconsign is used by default. (The actual file name(s) stored on disk may have an appropriated suffix appended by the dbm_module.) If file is not an absolute path name, the file is placed in the same directory as the top-level SConstruct file.

If file is None, then scons will store file signatures in a separate .sconsign file in each directory, not in one global database file. (This was the default behavior prior to SCons 0.96.91 and 0.97.)

The optional dbm_module argument can be used to specify which Python database module The default is to use a custom SCons.dblite module that uses pickled Python data structures, and which works on all Python versions from 1.5.2 on.

Examples:

# Explicitly stores signatures in ".sconsign.dblite"
# in the top-level SConstruct directory (the
# default behavior).
SConsignFile()

# Stores signatures in the file "etc/scons-signatures"
# relative to the top-level SConstruct directory.
SConsignFile("etc/scons-signatures")

# Stores signatures in the specified absolute file name.
SConsignFile("/home/me/SCons/signatures")

# Stores signatures in a separate .sconsign file
# in each directory.
SConsignFile(None)

env.SetDefault(key=val, [...])

Sets construction variables to default values specified with the keyword arguments if (and only if) the variables are not already set. The following statements are equivalent:

env.SetDefault(FOO = 'foo')

if not env.has_key('FOO'): env['FOO'] = 'foo'

SetOption(name, value)

env.SetOption(name, value)

This function provides a way to set a select subset of the scons command line options from a SConscript file. The options supported are: clean which corresponds to -c, --clean, and --remove; duplicate which corresponds to --duplicate; implicit_cache which corresponds to --implicit-cache; max_drift which corresponds to --max-drift; num_jobs which corresponds to -j and --jobs. See the documentation for the corresponding command line object for information about each specific option. Example:

SetOption('max_drift', 1)

SideEffect(side_effect, target)

env.SideEffect(side_effect, target)

Declares side_effect as a side effect of building target. Both side_effect and target can be a list, a file name, or a node. A side effect is a target that is created as a side effect of building other targets. For example, a Windows PDB file is created as a side effect of building the .obj files for a static library. If a target is a side effect of multiple build commands, scons will ensure that only one set of commands is executed at a time. Consequently, you only need to use this method for side-effect targets that are built as a result of multiple build commands.

SourceCode(entries, builder)

env.SourceCode(entries, builder)

Arrange for non-existent source files to be fetched from a source code management system using the specified builder. The specified entries may be a Node, string or list of both, and may represent either individual source files or directories in which source files can be found.

For any non-existent source files, scons will search up the directory tree and use the first SourceCode builder it finds. The specified builder may be None, in which case scons will not use a builder to fetch source files for the specified entries, even if a SourceCode builder has been specified for a directory higher up the tree.

scons will, by default, fetch files from SCCS or RCS subdirectories without explicit configuration. This takes some extra processing time to search for the necessary source code management files on disk. You can avoid these extra searches and speed up your build a little by disabling these searches as follows:

env.SourceCode('.', None)

Note that if the specified builder is one you create by hand, it must have an associated construction environment to use when fetching a source file.

scons provides a set of canned factory functions that return appropriate Builders for various popular source code management systems. Canonical examples of invocation include:

env.SourceCode('.', env.BitKeeper('/usr/local/BKsources'))
env.SourceCode('src', env.CVS('/usr/local/CVSROOT'))
env.SourceCode('/', env.RCS())
env.SourceCode(['f1.c', 'f2.c'], env.SCCS())
env.SourceCode('no_source.c', None)

env.subst(string, [raw, target, source, conv])

Performs construction variable interpolation on the specified string argument.

By default, leading or trailing white space will be removed from the result. and all sequences of white space will be compressed to a single space character. Additionally, any $( and $) character sequences will be stripped from the returned string, The optional raw argument may be set to 1 if you want to preserve white space and $(-$) sequences. The raw argument may be set to 2 if you want to strip all characters between any $( and $) pairs (as is done for signature calculation).

The optional target and source keyword arguments must be set to lists of target and source nodes, respectively, if you want the $TARGET, $TARGETS, $SOURCE and $SOURCES to be available for expansion. This is usually necessary if you are calling env.subst() from within a Python function used as an SCons action.

By default, all returned values are converted to their string rep